Win 95 - Teilrekonstruktion Lost Frameset? YiYa's Home

Wenn Schulungsnetze auch in mancherlei Hinsicht recht einfach strukturiert sind, so bereitet die Gewährleistung einer funktionierenden und einheitlichen Arbeitsumgebung für die meist ungeübten Schüler doch eine Reihe von Problemen - zumindestens aber eine Menge Arbeit.

Um für Schüler und Dozenten ärgerliche Unterschiede in der Konfiguration der Schulungsrechner zu vermeiden und Rechnerausfällen vorzubeugen, verwende ich für Windows 95 ein 2stufiges Rekonstruktions-Verfahren, ergänzt durch die Sperrung verschiedener Manipulationsmöglichkeiten.

Das Verfahren rekonstruiert beim Rechnerstart die wichtigsten Windows-Dateien anhand einiger teils lokal, teils auf dem File-Server abgelegter Backup-Dateien und kann in einer einfachen Variante schon über einige Batch-Dateien realisiert werden. Eine elegantere und vielfältigere Lösung bietet das Programm "Win 95 Restore".

  1. Schritt: lokale Rek. der Registry und anderer, für den Windows-Start notwendiger Dateien
  2. Schritt: Rek. des Desktops, des Menüsystems und weiterer Dateien
  3. Schritt: Sperren einiger Zugriffsmöglichkeiten

1. lokale Rekonstruktion der Registry

1.1 C:\AUTOEXEC.BAT

In der Startdatei werden die Systemvariablen "RaumID" und "PlatzID" zur späteren Identifizierung des Schulungsraums und des Arbeitsplatzes definiert und dann die Batch-Datei C:\SERVICE\W95RL.BAT aufgerufen (soweit vorhanden):

@echo off
:
set raumid=R429
set platzid=R429-01
if exist c:\service\w95rl.bat call c:\service\w95rl.bat
:

1.2 C:\SERVICE\W95RL.BAT

kopiert die Registry und evt. weitere, für den Windows-Start benötigte Dateien in das Windows-Verzeichnis:

@echo off
echo Rekonstruiere Registry für Rechner %PLATZID% ...
attrib -s -h -r c:\windows\system.d* >nul:
attrib -s -h -r c:\windows\user.d* >nul:
xcopy c:\service\windows\*.* c:\windows\*.* /S/E > nul:
attrib +s +h c:\windows\system.d* >nul:
attrib +s +h c:\windows\user.d* >nul:
echo.

1.3 F:\STAMP\PREP.BAT

kann zum Erstellen der erforderlichen lokalen Kopien der Registry und weiterer für den Windows-Start nötiger Dateien verwendet werden:

@echo off
echo Einrichtung der lokalen Restaurations-Verzeichnisse
echo ---------------------------------------------------
md  c:\service > nul:
del c:\service\windows\*.da0
xcopy c:\windows\sys*.dat   c:\service\windows\*.* /c/h/r
xcopy c:\windows\use*.dat   c:\service\windows\*.* /c/h/r
rem ---- Weitere Dateien für den Windows-Start ----
xcopy c:\windows\system.ini c:\service\windows\*.* /c/r
xcopy c:\windows\win.ini    c:\service\windows\*.* /c/r
rem ---- Attribute zurücksetzen ----
attrib -s -h -r c:\service\windows\*.*
rem ---- Rekonstruktion einschalten ----
call f:\stamp\on.bat

1.4 F:\STAMP\OFF.BAT

schaltet die Rekonstruktion zeitweilig, durch umbenennen der Datei W95RL.BAT aus. Dies wird evt. nötig, wenn im Rahmen einer Programminstallation ein Neustart des Rechners erforderlich ist. Bliebe die Rekonstruktion dabei aktiv, so gingen alle bis dahin vorgenommenen Änderungen der Registry verloren!

@echo off
if exist c:\service\w95rl.bat ren c:\service\w95rl.bat offrl.bat

1.5 F:\STAMP\ON.BAT

wird von "PREP.BAT" zum Einschalten der Rekonstruktion verwendet und kann ferner zum Wieder-Einschalten der Restauration, ohne erneute Anlage der Backup-Dateien benutzt werden.

@echo off
if exist c:\service\offrl.bat ren c:\service\offrl.bat w95rl.bat
if not exist c:\service\w95rl.bat copy f:\stamp\rall\service\w95rl.bat c:\service\w95rl.bat


2. Rekonstruktion des Desktops und des Startmenüs

Die Rekonstruktion des Desktops, des Startmenüs und anderer Dateien kann erst erfolgen, wenn mit dem Start von Windows die Unterstützung langer Dateinamen aktiviert wurde. Zur Rekonstruktion kann eine Batch-Datei wie W95RN.BAT oder das Programm W95RN.EXE eingesetzt werden.

2.1 F:\STAMP\W95RN.BAT

@echo off
 rem ---- Prüfen ob Rekonstruktion eingeschaltet ist ----
 if not exist c:\service\w95rl.bat goto ENDE
 rem ---- Temporäre Dateien löschen ----
 deltree /y c:\temp\*.*
 rem ---- Dokumenten-Menü löschen ----
 if exist c:\windows\recent\*.lnk del c:\windows\recent\*.lnk > nul:
 rem ---- Einige Datenverzeichnisse prüfen ----
 if not exist c:\daten\con md c:\daten
 if not exist c:\daten\excel\con md c:\daten\excel
 :
 rem ---- Desktop und Startmenü löschen ----
 deltree /y c:\windows\desktop >nul:
 deltree /y c:\windows\startmenü >nul:
 rem ---- Desktop,Startmenü und andere Dateien neuaufbauen ----
 xcopy f:\stamp\rall\*.*      c:\*.* /s/e/c/i/q/r/h
 xcopy f:\stamp\%raumid%\*.*  c:\*.* /s/e/c/i/q/r/h
 xcopy f:\stamp\%platzid%\*.* c:\*.* /s/e/c/i/q/r/h
:ENDE

Anm.: Für diese Batch-Datei sollten die Eigenschaften "Ausführen in Symbolgröße" und "automatisches Ende" vereinbart werden und die dadurch erzeigte PIF-Datei in das Verzeichnis von W95RN.BAT kopiert werden.

2.2 Mögliche Aufrufarten für W95RN.BAT:

Zum Aufruf im Rahmen des Windows-Starts existieren verschiedene Möglichkeiten:

1. Aufruf durch eine Verknüpfung im Windows Autostart-Ordner.
  Eine naheliegende, aber wenig empfehlenswerte Möglichkeit, da durch Manipulationen des Menüsystems die Rekonstruktion leicht ausfallen kann.
2. Aufruf innerhalb bzw. beim Verlassen des Anmeldeskripts
  Bei Netware-Netzen eine sichere Methode (Exit-Befehl oder Aufruf des Commandointerpreters, z.B.: #command.com /c f:\stamp\w95rn.bat)
3. Eintrag in der WIN.INI (empfohlen)
  Mit dem Eintrag "run=f:\stamp\w95rn.bat" kann ein hinreichend sicherer Aufruf erfolgen, wenn die Datei WIN.INI im Rahmen der 1. Rekonstruktionsphase mit den Registry-Dateien lokal wiederhergestellt wird.
4. Eintrag in der Registry (empfohlen)
  Mit den Programmen PolEdit oder RegEdit kann der Aufruf durch einen Registry-Eintrag in der "Run"-Rubrik bewirkt werden:
Rubrik: HKEY_LOCAL_MACHINE\Software\Microsoft\Windows\CurrentVersion\Run
Schlüssel: Win95Restore = f:\stamp\w95rn.bat

2.3 Anlage der Backup-Dateien

Auf 3 Differenzierungsebenen können auf dem Server (Verzeichnis F:\Stamp) die Rekonstruktionsverzeichnisse "RALL", "RAUM" und "RECHNER" bereitgestellt werden - wobei die Bezeichnungen RAUM und RECHNER durch die vergebenen Kennungen für RaumID und PlatzID zu ersetzten sind!

In diese Verzeichnisse werden die Originaldateien kopiert - jeweils in den Verzeichnisstrukturen, in denen sie auf C: benötigt werden (ab dem Wurzelverzeichnis).

Beispiele:

Um einen einheitlichen Desktop in allen Schulungsräumen zu erhalten, kopieren Sie das Verzeichnis C:\WINDOWS\DESKTOP in das Verzeichnis F:\STAMP\RALL\WINDOWS\DESKTOP.
Um innerhalb des Raums 401 ein einheitliches Startmenü zu garantieren, kopieren Sie das Verzeichnis C:\WINDOWS\STARTMENÜ inklusive aller Unterverzeichnisse in das Verzeichnis F:\STAMP\R401\WINDOWS\STARTMENÜ.
Um auf dem Lehrerrecher R401-00 den zusätzlichen Menüpunkt "Telnet" unter Programme/Service zu erhalten, legen Sie das Verzeichnis F:\STAMP\R401-00\WINDOWS\STARTMENÜ\PROGRAMME\SERVICE an (oder kopieren es) und richten dort die Verknüpfung "Telnet.LNK" ein.

Bei der Rekonstruktion werden zuerst die Dateien und Verzeichnisse in RALL berücksichtigt (die, die auf allen Rechner in gleicher Form vorhanden sein sollen), dann (additiv) die aus dem RAUM-Verzeichnis (in einem Schulungsraum gleich) und evt. abschliessend die aus dem RECHNER-Verzeichnis (individuell auf einen einzelnen Rechner zugeschnitten).

3. Restriktionen

Mit dem Windows Programm "PolEdit" können verschiedene Manipulationsmöglichkeiten der Windows-Oberfläche gesperrt werden, zum Teil zentral über eine allgemeine Systemrichtliniendatei auf dem Server - zum Teil benutzerspezifisch, durch eine direkte Änderung der lokalen Registry. Auf der Seite Restriktionen finden Sie eine Übersicht der möglichen Sperrungen.

Poledit selbst finden Sie auf der Windows Installations-CD, bei Windows 98 z.B. im Verzeichnis \TOOLS\RESKIT\NETADMIN\POLEDIT

Das Programm kann nebst der Vorlagendatei "admin.adm" in ein Serververzeichnis kopiert werden und dann von dort aufgerufen werden.

Eine einfache Alternative bietet das Programm W95RN.EXE.


Print  Top - Letzte Aktualisierung: 29.06.2004